REM This QuickSort routine was given to me by John Davies - and he asked for me to distribute it around newsgroups. It's for OPL32 - enjoy: 

PROC Main: 
 LOCAL Generation(100), i% 

 REM Fill up Generation() with some numbers for the demo 
 i%=1 
 DO 
  Generation(i%)=INT(RND*1000) 
  i%=i%+1 
 UNTIL i%>100 

 Show:(ADDR(Generation(1)),100) 
 PRINT 
 QSort:(ADDR(Generation(1)),0,99) 
 Show:(ADDR(Generation(1)),100) 
GET 
ENDP 

PROC Show:(PArray&,size%) 
 LOCAL i% 

 i%=0 
 DO 
  PRINT PEEKF(PArray&+i%*8), 
  i%=i%+1 
 UNTIL i%>=size% 
ENDP 

PROC QSort:(PArray&,lo0%,hi0%) 
 LOCAL lo%,hi%,mid 
 lo%=lo0% : hi%=hi0% 

 IF hi0%>lo0% 
  mid=PEEKF(PArray&+((lo0%+hi0%)/2*8)) 
  WHILE lo%<=hi% 
   WHILE lo%<hi0% AND PEEKF(PArray&+lo%*8)<mid 
    lo%=lo%+1 
   ENDWH 
   WHILE hi%>lo0% AND PEEKF(PArray&+hi%*8)>mid 
    hi%=hi%-1 
   ENDWH 
   IF lo%<=hi% 
    Swap:(PArray&,lo%,hi%) 
    lo%=lo%+1 
    hi%=hi%-1 
   ENDIF 
  ENDWH 
  IF lo0%<hi% 
   QSort:(PArray&,lo0%,hi%) 
  ENDIF 
  IF lo%<hi0% 
   QSort:(PArray&,lo%,hi0%) 
  ENDIF 
 ENDIF 
ENDP 

PROC Swap:(PArray&,i%,j%) 
 LOCAL T 
 T=PEEKF(PArray&+i%*8) 
 POKEF (PArray&+i%*8),PEEKF(PArray&+j%*8) 
 POKEF (PArray&+j%*8),T 
ENDP 

REM Don't forget to pass 0 and n-1 to QSort:() as in the demo since it's dealing with real arrays and not OPL's arrays. This function sorts and array of 1000 floats in just under 10 seconds, 50 is well under 1/2 second, too quick to time anyway. (All timings were on a Psion 5). 

REM Cheers John :^) 

REM Chris Harrison 
REM http://www.btinternet.com/~harrison/