REM Please feel to use parts of this code in your own programs,
REM however please do not modify it and redistribute it.
REM If you believe you have made a useful modification to the code
REM however, please do email me and tell me at gary.ewer@earthling.net

REM APP Character
REM 	type 0
REM	icon "\OPD\char"
REM ENDA

PROC ASC:
  GLOBAL x%,z%,a%,b%,menu%,id%,id2%, c%(6)
  LOCK ON
  BUSY "Please Wait",3
  id%=gCREATE (0,0,480,384,1)
  id2%=gCREATE (0,0,480,160,1,1)
  gBORDER $203
  gAT (480-300)/2,(160-80)/2-3
  gBUTTON "",1,300,80,0
  gFONT 8
  gAT 136,72-3
  gPRINT "CHARACTER MAP v1.0"
  gAT 128,100-3
  gPRINT "For use with Psion Series 3a"
  gFONT 6
  gAT 166,150
  gPRINT "¸ Gary Ewer 1997"
  gUSE id%
  gUPDATE OFF
  x%=1
  z%=257
  a%=1
  b%=11
  gFONT 1
  DO
    gAT a%,b%
    gPRINT ""+CHR$(x%)+"" :gAT a%+13,b% :gPRINT " =  "+FIX$(x%,0,100)
    x%=x%+1
    a%=a%+60 REM 12
    IF a%=1+(60*8) REM 11+(32*12)
      b%=b%+12
      a%=1
    ENDIF
    IF x%=257
      BREAK
    ENDIF
  UNTIL x%=z%
  z%=0
  BUSY OFF
  GIPRINT "Press any Key",1
  GET
  LOCK OFF
  GIPRINT "",1
  gCLOSE id2%
  DO
    x%=0
    GETEVENT c%()
    IF c%(1)=$405
      STOP
    ELSE
      x%=c%(1)
    ENDIF
    IF x%=291 or x%=%h+512
      Help:
    ENDIF
    IF x%=%i+512
      credits:
    ENDIF
    IF x%=%x+512
      STOP
    ENDIF
    IF x%=290
      mINIT
      mCARD "Options","Help",%h,"Info",%i,"Exit",%x
      menu%=MENU
      IF menu%=%x
        STOP
      ELSEIF menu%=%h
        help:
      ELSEIF menu%=%i
        credits:
      ENDIF
    ENDIF
    IF x%=(257)
      z%=z%-12
    ELSEIF x%=(256)
      z%=z%+12
    ELSEIF x%=(260)
      z%=z%+120
    ELSEIF x%=(261)
      z%=z%-120
    ENDIF
    IF z%<=-228
      z%=-228
    ENDIF
    IF z%>=0
      z%=0
    ENDIF
    gSETWIN 0,z%
  UNTIL x%=(27)
ENDP

PROC Credits:
  LOCK ON
  dINIT "Info"
  dTEXT "","This program was written by Gary Ewer.",2
  dTEXT "","If you like this program and you use it a lot please feel free",2
  dTEXT "","to send tokens of your appreciation to the following address:",2
  dTEXT "","7 Sutton Park, Sutton, Ely, Cambs, CB6 2RP. ENGLAND.",2
  dTEXT "","If you have any suggestions for this program, want help or want",2
  dTEXT "","information on any of my other programs you can either contact me",2
  dTEXT "","at the above address or e-mail me at ""gary.ewer@earthling.net""",2
  dTEXT "","- I'd be pleased to hear from you.",2
  DIALOG
  LOCK OFF
ENDP

PROC help:
  LOCK ON
  dINIT "Help - navigation"
  dTEXT "","To navigate up and down the page just use:",2
  dTEXT "",""+CHR$(24)+", "+CHR$(25)+", "+CHR$(2)+""+CHR$(24)+" or "+CHR$(2)+""+CHR$(25)+".",2
  dTEXT "","Also you can use the menu key and it's various shortcuts.",2
  dTEXT "","To get to this screen quickly you can just press the help key.",2
  dTEXT "","To Quit you can either use Esc, "+CHR$(2)+"Esc or "+CHR$(2)+"X.",2
  DIALOG
  dINIT "Help - copying to other applications"
  dTEXT "","When you find the character you want just go",2
  dTEXT "","to an application and hold down the control button",2
  dTEXT "","and type in the appropriate number",2
  dTEXT "","(3 numbers long [add 0's if necessary]). e.g Control-035 for "+CHR$(35)+".",2
  dTEXT "","Please note - the characters for numbers 1-32 do not seem to",2
  dTEXT "","be availiable in word etc. It seems you can only get them in",2
  dTEXT "","OPL programs.",2
  DIALOG
  LOCK OFF
ENDP